OCS ./ HIT: Geometry Patent Stops Shareware Project

http://www.delphion.com/details?&pn=WO00104742A1

//========================================================================
// Compute H1 and H2 such that P = 2*H1 = 2*H2 (if such halves exist)
// Return TRUE iff the halves exist.
//========================================================================
function TGF2NECurve.Halves(H1, H2, P: TGF2NEPoint): Boolean;
begin
  //--- Check
  if fStatus <> csHasCoefs then ErrorNoCoefs('Halves');
 
  //--- P = Identity ?
  if P.IsO then
  begin
    GetOrder2Point(H1);
    H2.SetO;
    Result := true;
    Exit;
  end;
 
  with fField do
  begin
    //--- Compute T = X + Y/X (X and Y are unknow)
    //    Solve f(T) = T² + T + A + Px
    GF2Set(H2.fY,fA);
    Add(H2.fY,P.fX);
    Result := SolveQuad(H1.fX,H2.fY); //H1.fX is used for "T"
    if not Result then
    begin
      H1.SetO;
      H2.SetO;
      Exit;
    end;
    //--- The 2 roots T and T+1 lead to the 2 halves H1 and H2
    GF2Set(H2.fY,H1.fX);
    GF2Set(H1.fY,H1.fX);
    Add1(H1.fY); //!And not GF2Add1 because of possible Normal Basis
    GF2Set(H2.fX,H1.fY);
    //--- Compute H1.X
    //    X := (T Px + Py)^(1/2)
    Mul(H1.fX,P.fX);
    Add(H1.fX,P.fY);
    SqrRoot(H1.fX);
    //--- Compute H1.Y
    //    Y := X (X + T + 1)
    Add(H1.fY,H1.fX);
    Mul(H1.fY,H1.fX);
    //--- Compute H2.X
    //    X := ((T + 1) Px + Py)^(1/2)
    Mul(H2.fX,P.fX);
    Add(H2.fX,P.fY);
    SqrRoot(H2.fX);
    //--- Compute H2.Y
    //    Y := X (X + T)
    Add(H2.fY,H2.fX);
    Mul(H2.fY,H2.fX);
  end;
end;